set rs_booklist=Server.CreateObject("ADODB.RecordSet")
sql="SELECT BookID, BookName, author FROM DB_bookinfo ORDER BY BookID"
rs_booklist.open sql,conn,1,3 'conn是自己写的一个连接数据库函数
If rs_booklist.Bof AND rs_booklist.Eof Then
Response.Write "没有数据"
Else
Dim page_size '此变量用来存放每一页的记录数。
Dim page_nonce '此变量用来存放当前页的页码。
Dim page_total '此变量用来存放总页数。
page_size=7 '将第一页记录数设置为7条。
rs_booklist.PageSize=page_size
page_total=rs_booklist.PageCount
'下面5句，是判断网页是不是刚打开，若是，则将1赋给变量page_nonce（即当前页为第一页）,
'若不是，则将由Request对象的Querystring集合从HTTP查询字符串中获取来的变量值（当前页码）赋给变量page_nonce。
If Request.QueryString("page_nonce")<>"" Then
page_nonce=Cint(Request.QueryString ("page_nonce"))
Else
page_nonce=1
End If
'将当前页码赋给记录集对象的表示当前记录页号的属性（AbsolutePage）。
rs_booklist.AbsolutePage=page_nonce
Dim I
I=page_size
'通过Do While 循环语句，将当前页的每一条记录读取出来。
Do While Not rs_booklist.Eof And I>0
I=I-1
Response.Write "<tr align='center'>"
Response.Write "<td height='10'>" & rs_booklist("BookID") & "</td>"
Response.Write "<td height='10'>" & rs_booklist("BookName") & "</td>"
Response.Write "<td height='10'>" & rs_booklist("author") & " </td>"
'将记录指针移动到下一条记录。
rs_booklist.MoveNext

Loop
Response.Write "</table>"
'开始做分页连接。
Response.Write "<p align='center'>分页: "
'通过For 循环将除当前页码号之外的每一个页码号做一个超连接，
For j=1 To page_total
If j=page_nonce Then
Response.Write j & "&nbsp"
Else
Response.Write "<a href='booklist.asp?page_nonce=" & j & "'>" & j & "</a>&nbsp"
End If
Next
End If
rs_booklist.Close
Set rs_booklist=nothing
Conn.Close
Set Conn=nothing